1. Créez un nouveau projet que vous enregistrez sous le nom Ex_12xx.vbp. La feuille porte le nom F_GrosTexte et sa propriété CAPTION indique Afficher un texte volumineux. 

2. Ajoutez ensuite une zone de texte que vous nommez ZT_Vol. Sa propriété TEXT est vide. HEIGHT  indique 2415 et WIDTH, 6615. Enfin, la propriété MULTILINE doit être initialisée à True.

3. Placez une barre de défilement vertical à droite de la zone de texte. Nommez-la DV_Droite.

4. Définissez ensuite une constante indiquant le nombre maximum de lignes à afficher et une variable dimensionnée pour contenir toutes les lignes du texte.

Private Const V_LIGNES = 15
Private V_Texte() As String

5. Il faut ensuite charger le contenu du texte dans la variable dimensionnée lors de l'événement FORM_LOAD. Pour ce faire, on utilise le code suivant.

Private Sub Form_Load()
   Dim V_N as Integer  'Déclaration de variable

 'Initialiser le tableau de chaînes dynamique à partir du fichier texte
   'Ouverture du fichier
   Open "c:\Program files\internet explorer\readme.txt " For Input As #1 Len = 1024 
   Do Until EOF(1)   'Boucle jusqu'à ce qu'on atteigne la fin du texte
      V_N = V_N + 1   'Compteur
      ReDim Preserve V_Texte(V_N + V_LIGNES)  'Redimensionner le tableau
      Line Input #1, V_Texte(V_N)   'Lecture d'une ligne de texte
   Loop
   Close #1   'Fermeture du fichier

'Définir les propriétés de la barre de défilement
   With DV_Droite   'Identification du contrôle utilisé
      .Min = 1   'Minimum
      .Max = V_N   'Maximum
      .SmallChange = 1   'Modifications suite à un clic sur une flèche
      .LargeChange = V_N \ 10   'Modifications suite à un clic sur une zone
   End With
End Sub

6. On poursuit en ajoutant une section de code à la barre de défilement afin de faire afficher le texte dans la zone à cet effet.

Private Sub DV_Droite_Change()
   Dim V_I  As Integer
   Dim V_Chaine As String

   'Créer la chaîne à afficher à partir des éléments du tableau
   For V_I = DV_Droite.Value To DV_Droite.Value + V_LIGNES
      V_Chaine = V_Chaine + V_Texte(V_I) + vbCrLf
   Next V_I
   ZT_Vol.Text = V_Chaine
End Sub

7. Il ne vous reste plus qu'à sauvegarder ce programme et à le tester.

Application:

• Trouvez un autre fichier texte (.TXT), si possible de plus de 64 Ko, et effectuez les changements nécessaires pour le faire afficher.  Enregistrez votre nouvelle version sous le nom  Ex_12bxx.vbp.